create procedure sp_hogehoge @inum int as
begin
  --何かの処理
  --その処理結果に基づき変数やテーブルをSELECTする
  select * from ksale where empno = @inum
end

exec sp_hogehoge 7

ORACLE　MSSQL　SSA　MySQL　

--Transact-SQLサンプル
begin
  --変数宣言
  declare @mystr varchar(20), @mycnt int

  --値の代入
  select @mycnt = 0
  select @mystr = '文字'

  --IF文
  if (@mycnt = 0)
    begin
      select @mystr = '文字２'
      print @mystr
    end
  else
    print '文字３'

  --CASE文
  select @mystr = case month(getdate())
             when 1 then '1月'
             when 2 then '2月'
             when 3 then '3月'
             when 4 then '4月'
             else '1～4月以外'
           end
  print @mystr

  --WHILE-LOOP
  while (@mycnt <= 5)
  begin
    select @mycnt = @mycnt + 1
    print  @mycnt
  end

  --BEGIN～ENDブロック内でのSELECT文の発行
  select 日付 = getdate()

end
go

ORACLE　MSSQL　SSA　MySQL　

--Transact-SQLサンプル（カーソルLOOPを使用するストアドプロシージャ）

if exists (select * from sysobjects where id = object_id('dbo.sp_hoge') and sysstat & 0xf = 4)
	drop procedure dbo.sp_hoge
go

create procedure sp_hoge @inum int as
--変数宣言
declare @mystr varchar(50)

--カーソル使用列
declare @empnm varchar(40)
declare @job varchar(20)
--カーソル宣言
deallocate mycur --同一セッション内で使う場合必要
declare mycur cursor for
select empnm,job from kemp where deptno = @inum

--カーソルオープン
open mycur

--FETCH（行の取り出し）
fetch next from mycur into @empnm, @job

--LOOP

while (@@fetch_status <> -1) --エラーまたはEOFでない間
begin
    if (@@fetch_status <> -2) --EOFでなければ何か処理をする
    begin
        if @job = 'スタッフ'
            select @mystr = '営業スタッフ：'
        else
            select @mystr = ''
        print @mystr + @empnm
    end
    --FETCH（行の取り出し）
    fetch next from mycur into @empnm, @job
end

--カーソルクローズ
close mycur

return
go

--ストアドプロシージャ実行
exec sp_hoge 1
go

ORACLE　MSSQL　SSA　

--Transact-SQLサンプル（OUTパラメータを使用するストアドプロシージャ）

if exists (select * from sysobjects where id = object_id('dbo.sp_hoge_outp') and sysstat & 0xf = 4)
	drop procedure dbo.sp_hoge_outp
GO

create procedure sp_hoge_outp @ovar varchar(30)=null output as
  --何やかやの処理
  --何やかやの処理終わり
  --OUTパラメータにセット
  select @ovar = 'アウト！'
  return
go

--ストアドプロシージャ実行
declare @myout varchar(30)
exec sp_hoge_outp @ovar = @myout output
select @myout
go

ORACLE　MSSQL　SSA　

--Transact-SQLサンプル（動的SQLを使用するストアドプロシージャ）
--EXECUTE(文字列) を使用します ※カッコで括らないとエラーになるので注意
if exists (select * from sysobjects where id = object_id('dbo.sp_hoge_dyna') and sysstat & 0xf = 4)
	drop procedure dbo.sp_hoge_dyna
GO

create procedure sp_hoge_dyna
@kbn varchar(1),
@inum int as
  --変数宣言
  declare @sqlstmt varchar(200)

  --SQL文生成（区分：１の時は部署番号に該当する社員名、以外は部署名）
  if @kbn = '1'
      select @sqlstmt = 'select empnm from kemp where deptno = ' + cast(@inum as varchar(2))
  else
      select @sqlstmt = 'select deptnm from kdept where deptno = ' + cast(@inum as varchar(2))

  --SQL文実行
  execute (@sqlstmt)
  return
go

--ストアドプロシージャ実行（部署番号：１の社員表示）
exec sp_hoge_dyna @kbn = '1' , @inum = 1
--ストアドプロシージャ実行（部署番号：１の部署名表示）
exec sp_hoge_dyna @kbn = '2' , @inum = 1
go

ORACLE　MSSQL　SSA　

--Transact-SQLサンプル（一時テーブルを使用するストアドプロシージャ）
--CREATE TABLE #テーブル名 を使用します（テーブル名の先頭に # を付ける）
if exists (select * from sysobjects where id = object_id('dbo.sp_hoge_tmp') and sysstat & 0xf = 4)
	drop procedure dbo.sp_hoge_tmp
GO

create procedure sp_hoge_tmp as

  --一時テーブル作成
  create table #tmpkemp (empnm varchar(40))

  --社員マスタから一時テーブルに格納
  insert into #tmpkemp select empnm from kemp

  --一時テーブルから社員名一覧表示
  select empnm from #tmpkemp
  return
go

--ストアドプロシージャ実行
exec sp_hoge_tmp
go

ORACLE　MSSQL　SSA　

--Transact-SQLサンプル（外部のコマンドやアプリケーションを使用するストアドプロシージャ）
--システムストアドプロシージャxp_cmdshellを使用します。
--※xp_cmdshellは『悪魔のストアド』です。サンプルを見ればわかると思いますが、データベースユーザーが
--　サーバー上でコマンドで実行できる事は『すべて xp_cmdshell から実行可能』です。
--　ですから、セキュリティ面を考慮して使用不可にしているWEBサイトも多いようです。
if exists (select * from sysobjects where id = object_id('dbo.sp_hoge_cmd') and sysstat & 0xf = 4)
	drop procedure dbo.sp_hoge_cmd
GO

create procedure sp_hoge_cmd as
  execute xp_cmdshell 'echo MSSQL > c:\xpcmd.txt'
  execute xp_cmdshell 'dir c:\*.txt >> c:\xpcmd.txt'
  return
go

--ストアドプロシージャ実行
exec sp_hoge_cmd
go

ORACLE　MSSQL　

declare @cmdstr varchar(1000)

--BCPコマンドを文字列として生成する
set @cmdstr = 'bcp "select * from misc.dbo.kcust" queryout c:\cust.txt -c -t , -U sa -P -o c:\cust.log'

--生成したコマンド文字列を実行するxp_cmdshellを動的SQLで実行する
execute master.dbo.xp_cmdshell @cmdstr

ORACLE　MSSQL　

101,新規顧客１株式会社
102,新規顧客２株式会社
103,新規顧客３株式会社
104,新規顧客４株式会社

--BULK INSERT を実行（newcust.txtの内容をkcustにINSERTする）
bulk insert kcust
from 'c:\newcust.txt'
with
(
  fieldterminator = ',',
  rowterminator = '\n'
)

ORACLE　MSSQL　

--SQL Mailクライアントセッションの起動、プロファイルの設定、等の詳細は
--Books Online参照。
--ローカル システム アカウントではなくドメイン アカウントを使って 
--MSSQLServer サービスを起動するように設定する必要がある
exec master.dbo.xp_sendmail  
  @recipients = 'email@uwaaaa.com;email2@uwaaaa.com;' --宛先
  ,@subject = '送信テスト' --タイトル
  ,@copy_recipients = 'email3@uwaaaa.com' --cc
  ,@blind_copy_recipients = 'email4@uwaaaa.com' --bcc
  ,@Message = 'このメールはxp_sendmailで送りました' --本文
  ,@attachments = 'c:\hoge.txt' --添付ファイル
  ,@query = 'select getdate()' --クエリー

ORACLE　MSSQL　

/* COM Automation（sp_OAxxx）サンプル      */
/* Excelファイルは消しておく必要があります */
DECLARE @hr int
DECLARE @objXls int
DECLARE @workBooks int
DECLARE @workBook int
DECLARE @workSheet int
DECLARE @workSheet1 int
DECLARE @range int
DECLARE @lines int
DECLARE @filename varchar(255)
DECLARE @strExec varchar(255)

DECLARE @source varchar(255)
DECLARE @description varchar(255)

set @filename = 'c:\test\spoa.xls'

/* オブジェクト生成 */
EXEC @hr = sp_OACreate 'Excel.Application', @objXls OUT

/* エラーハンドリング割愛
IF @hr != 0
  BEGIN
    EXEC @hr = sp_OAGetErrorInfo @objXls, @source OUT, @description OUT
    SELECT 'Source: ' + @source
    SELECT 'Description: ' + @description
  END
*/

EXEC @hr = sp_OAGetProperty @objXls ,'WorkBooks', @WorkBooks OUT

EXEC @hr = sp_OAGetProperty @WorkBooks, 'Add', @WorkBook OUT

/* セルに値をセット */
EXEC @hr = sp_OAGetProperty @objXls, 'Range("A1")', @Range OUT 
EXEC @hr = sp_OASetProperty @Range, 'Value', 'EmpCode'
EXEC @hr = sp_OAGetProperty @objXls, 'Range("B1")', @Range OUT 
EXEC @hr = sp_OASetProperty @Range, 'Value', 'EmpName'

/* セルに値をセット */
EXEC @hr = sp_OAGetProperty @objXls, 'Range("A2")', @Range OUT 
EXEC @hr = sp_OASetProperty @Range, 'Value', 'E001'
EXEC @hr = sp_OAGetProperty @objXls, 'Range("B2")', @Range OUT 
EXEC @hr = sp_OASetProperty @Range, 'Value', '山田太郎'

/* 書式変更 */
EXEC @hr = sp_OAGetProperty @objXls,'Range("A1:B1")',@Range OUT
EXEC @hr = sp_OASetProperty @Range,'Font.ColorIndex', 23
EXEC @hr = sp_OASetProperty @Range,'Font.Bold', TRUE
EXEC @hr = sp_OASetProperty @Range,'Font.Name', 'Century'
/* 書式変更終わり */

/* ファイル保存 */
SELECT @strExec = 'SaveAs("' + @filename + '")'
EXEC @hr = sp_OAMethod @WorkBook, @strExec

/* 後処理 */
EXEC @hr = sp_OAMethod @WorkBook, 'Close'
EXEC @hr = sp_OADestroy @objXls